class CADeepField extends MovieClip {
	
	public var BITS = 200;
	public var RULESET = 30;
	public var BITSIZE = 5;
	
	public var depth:Number;
	public var dx:Number;
	public var dy:Number;
	public var cnt:Number;
	public var cellrow:String;
	
	public var cells:Array;
	
	public var txtRuleset:TextField;
	

	public var canvas:MovieClip;
	
	function onLoad() {
		cells = new Array();
		dx = 0;
		dy = 0;
		depth = 0;
		cnt = 0;
		
		// set single seed row
		initRow();
		initialize();
		drawCellRow();
		
		this.onKeyDown = function() {
			switch (Key.getCode()) {
				case 65:
				  // a
					initialize();
					drawCellRow();
					break;
				case 66:
					// b
					applyRule();
					drawCellRow();
					break;		
				case 67:
					// c
					initialize();
					setRuleSet(random(256));
					drawCellRow();
					break;
				default:
//					trace("Key.getCode: "+Key.getCode());
					break;
			}
		}
		
		Key.addListener(this);
	}

	function onMouseDown() {
		initialize();
	}
	
	function initialize() {
		// remove old cells
		while (cells.length>0) {
			var ca = cells.pop();
			ca.onEnterFrame = function() {
				if (this._alpha>0) {
					this._alpha-=this.da*2+5;
				} else {
					this.removeMovieClip();
				}
			}
		}
		
		dx = 0;
		dy = 0;
		cnt = 0;
		setRuleSet(30);
		initRow();
	}


	public function initRow() {
		cellrow = "";
		for (var i=0;i<BITS;i++) {
			if (i==Math.round(BITS/2)) {
				cellrow+="1";
			} else {
				cellrow+="0";
			}
		}
	}

	public function grow() {
		// repeatedly apply automata rule on cellrow
		drawCellRow();
		applyRule();
	}
	
	public function stayInFocus() {
		var sw = 790;
		var sh = 590;

		// zoom to the extents of a specific region
		var rA = sw/sh;
		var rB = canvas._width/canvas._height;
		// constrain to largest dimension
		var r:Number = (rA<rB) ? sw/canvas._width : sh/canvas._height;
		// set the new zoom
		_xscale = 100*r;
		_yscale = _xscale;
		_x = (sw - canvas._width/r)/2;
		_y = (sh - canvas._height/r)/2;
	}
	
	public function randomizeCells() {
		var newrow:String = "";
		for (var i = 0; i<BITS; i++) {
			if (random(2)) {
				newrow+="0";
			} else {
				newrow+="1";
			}
		}
		
		// set new row
		cellrow = newrow;
	}
	
	public function drawCellRow() {
		// render the row of cells
		for (var i=0;i<BITS;i++) {
			// Extract least significant bit using bitwise AND
			var lsb = cellrow.charAt(i);
			if (lsb=="1") {
				// create the movieclip for the bit
				var nombre:String = "bit" + depth;
				dx = Math.round(BITS/2) - i;
				var init = {_x:dx*BITSIZE,_y:dy*BITSIZE,_xscale:BITSIZE*.9,_yscale:BITSIZE*.9,_alpha:0,da:dy+1};
				var neo:MovieClip = canvas.attachMovie("bitSquare", nombre, depth++, init);
				neo.onEnterFrame = function() {
					if (this._alpha<100) {
						this._alpha+=this.da;
					} else {
						delete this.onEnterFrame;
					}
				}
				cells.push(neo);
			}
		}
		dy++;
	}
	
	public function applyRule() {
		var newrow:String = "";
		// calculate new row one cell at a time	
		for (var i = 0; i<BITS; i++) {
			// find middle rule bit
			var n0:String;
			var n1:String = cellrow.charAt(i);
			var n2:String;
			
			if (i == 0) {
				// loop around to end
				n0 = cellrow.charAt(BITS-1);
				n2 = cellrow.charAt(i+1);
			} else if (i == (BITS-1)) {
				// loop around to beginning
				n0 = cellrow.charAt(i-1);
				n2 = cellrow.charAt(0);
			} else {
				n0 = cellrow.charAt(i-1);
				n2 = cellrow.charAt(i+1);
			}
			var ruleNumber:Number =   4*Number(n2) + 2*Number(n1) + Number(n0);
			var ruleOutcome:Number = RULESET >> ruleNumber;
			var lsb = String(ruleOutcome%2);
			newrow += lsb;
		}	
		
		// set new row
		cellrow = newrow;
	}
	
	public function setRuleSet(R:Number) {
		RULESET = R;
		txtRuleset.text = String(R);
		drawRuleSet();
	}
	
	public function drawRuleSet() {
		for (var i=0;i<8;i++) {
			var nombre = "rlBox"+i;
			var init = {_x:i*40-160,_y:-50,val:i,rule:RULESET};
			var neo = this.attachMovie("ruleBox",nombre,10000+i,init);
		}
	}
	
	
}